1

我正在用 clojure 重写我的世界历史网站 (history.clmitchell.net) 并取得了很大进展。我已经到了需要使用条件来输出打嗝代码的地步，以根据我正在加载的页面声明 CSS 链接。我仔细研究了文档，但无法弄清楚：

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (condp = pageName
         "index" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css")
         "add" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/addform.css")
         "map" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/SpryCollapsiblePanel.css"
                                "/css/SpryAccordion.css")
         "chart" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/cha.css")
         "learn" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css"
                                  "/css/doc.css")
         "changes" (hic/include-css "/css/hcspry.css"
                                    "/css/menus.css"
                                    "/css/filter.css"
                                    "/css/wc3xhtml1.css"
                                    "/css/clg.css")
         "seek" (hic/include-css "/css/hcspry.css"
                                 "/css/menus.css"))
  (println (str  "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly.")))

问题：这种函数的正确语法是什么？

4

3 回答 3

2

您可以将您的 page-css 映射定义为一个单独的、普通的数据结构，并避免对 hic/include-css 的重复调用：

(def page-css-mapping
  {"index"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"]
   "add"     ["/css/hcspry.css"
              "/css/menus.css"
              "/css/addform.css"]
   "map"     ["/css/hcspry.css"
              "/css/menus.css"
              "/css/SpryCollapsiblePanel.css"
              "/css/SpryAccordion.css"]
   "chart"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/cha.css"]
   "learn"   ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"
              "/css/doc.css"]
   "changes" ["/css/hcspry.css"
              "/css/menus.css"
              "/css/filter.css"
              "/css/wc3xhtml1.css"
              "/css/clg.css"]
   "seek"    ["/css/hcspry.css"
              "/css/menus.css"]})

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (if-let [css-files (get page-css-mapping pageName)]
    (apply hic/include-css css-files)
    (println (str "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly."))))

现在您还可以将映射存储为纯数据结构（例如，作为 EDN 文件或在 Datomic 中），而不是对其进行硬编码。

于 2015-08-14T12:31:16.763 回答
1

你是说你不确定这个函数cssfiles在做什么？在这种情况下，函数说：

如果我的参数pagename等于字符串"index"，则执行include-css可以在命名空间中找到的hic函数"/css/hcspry.css"，缩写"/css/menus.css"为cssfiles

如果相反pagename等于"add"，则include-css使用一组不同的参数执行...，返回结果值...。（等等）

对于其他可预测值的字符串，依此类推pagename。

但是，如果pagename与我测试的任何字符串都不匹配，则执行表达式println末尾的语句condp以打印出错误消息。

condp有关语法的更多信息，请参阅文档。不过，如果需要，我很乐意提供更多详细信息。

于 2015-08-14T04:36:00.067 回答
0

dskrvk 是对的：println 表单不在 condp 表单中；这是更正后的函数：

(defn cssfiles
  "load sets of CSS files depending on which page is being served"
  [pageName]
  (condp = pageName
         "index" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css")
         "add" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/addform.css")
         "map" (hic/include-css "/css/hcspry.css"
                                "/css/menus.css"
                                "/css/SpryCollapsiblePanel.css"
                                "/css/SpryAccordion.css")
         "chart" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/cha.css")
         "learn" (hic/include-css "/css/hcspry.css"
                                  "/css/menus.css"
                                  "/css/filter.css"
                                  "/css/wc3xhtml1.css"
                                  "/css/doc.css")
         "changes" (hic/include-css "/css/hcspry.css"
                                    "/css/menus.css"
                                    "/css/filter.css"
                                    "/css/wc3xhtml1.css"
                                    "/css/clg.css")
         "seek" (hic/include-css "/css/hcspry.css"
                                 "/css/menus.css")
         (println (str  "PRGMR. MSG: net.clm.history.pages.snippets.clj::(defn cssfiles [" pageName "]): unknown parameter or parameter not processed properly."))))
于 2015-08-14T13:47:02.603 回答