1

大家好 -

我正在使用锚点和控制点使用curveTo创建形状。一切正常，但是当线条不直时，我无法弄清楚如何让我的线条穿过控制点（蓝点）的中心。

这是我绘制形状的代码：

           // clear old line and draw new / begin fill
        var g:Graphics = graphics;
        g.clear();
        g.lineStyle(2, 0, 1);
        g.beginFill(0x0099FF,.1);

        //move to starting anchor point
        var startX:Number = anchorPoints[0].x;
        var startY:Number = anchorPoints[0].y;
        g.moveTo(startX, startY);

        // Connect the dots
        var numAnchors:Number = anchorPoints.length;
        for (var i:Number=1; i<numAnchors; i++) {

            // curve to next anchor through control
            g.curveTo(controlPoints[i].x,controlPoints[i].y, anchorPoints[i].x, anchorPoints[i].y);

        }
        // Close the loop
        g.curveTo(controlPoints[0].x,controlPoints[0].y,startX,startY);

我正在绘制的形状以供参考：

如何修改我的代码以使线条直接通过蓝色控制点？

提前致谢！

b

4

1 回答 1

7

示例项目源代码

如果您对它的派生方式不感兴趣，请跳至答案部分。

背景资料


贝塞尔曲线很有趣，使用起来很有趣。此动画显示了如何在两个锚点（P0 和 P2）之间相对于控制点 (P1) 随着时间的推移绘制二次曲线。

您需要做的不是绘制控制点 (P1)，而是在 t=0.5 处绘制曲线上的点：

点 t=0.5
（来源：whilenotnull.com）

幸运的是，这很容易使用维基百科页面上给出的公式：http ://en.wikipedia.org/wiki/Bezier_Curve#Quadratic_B.C3.A9zier_curves

这是 Actionscript 中的公式：

public function calculatePoint(p0:Point, p1:Point, p2:Point, t:Number):Point
{
    var p:Point = new Point(calculateTerm(p0.x, p1.x, p2.x, t), calculateTerm(p0.y, p1.y, p2.y, t));
    return p;
}

public function calculateTerm(p0:Number, p1:Number, p2:Number, t:Number):Number
{
    var negT:Number = 1 - t;

    var a0:Number = Math.pow(negT, 2) * p0;
    var a1:Number = 2 * negT * t * p1;
    var a2:Number = Math.pow(t, 2) * p2;

    var pos:Number = a0 + a1 + a2;
    return pos;
}

因此，如果您插入三个点：var t0:Point = calculatePoint(p0, p1, p2, 0.5);您将获得曲线上要绘制“控制点”的点。

回答

现在我们可以编写一个函数，假设第二个参数是曲线上的一个点，并确定控制点的坐标：

public function derivePoint(p0:Point, b1:Point, p2:Point, t:Number = 0.5):Point
{
    var p:Point = new Point(deriveTerm(p0.x, b1.x, p2.x, t), deriveTerm(p0.y, b1.y, p2.y, t));
    return p;
}

public function deriveTerm(p0:Number, bt:Number, p2:Number, t:Number):Number
{
    var negT:Number = 1 - t;

    var a0:Number = Math.pow(negT, 2) * p0;
    var a1:Number = 2 * negT * t;
    var a2:Number = Math.pow(t, 2) * p2;

    var p1:Number = (bt - a0 - a2) / a1;
    return p1;
}

从此，我更新了您的代码片段，以（希望）通过您的“控制点”绘制曲线：

// clear old line and draw new / begin fill
var g:Graphics = graphics;
g.clear();
g.lineStyle(2, 0, 1);
g.beginFill(0x0099FF,.1);

//move to starting anchor point
var startX:Number = anchorPoints[0].x;
var startY:Number = anchorPoints[0].y;
g.moveTo(startX, startY);

// Connect the dots
var p0:Point = new Point(startX, startY);
var p2:Point;

var numAnchors:Number = anchorPoints.length;
for (var i:Number=1; i<numAnchors; i++) {

    p2 = new Point(anchorPoints[i].x, anchorPoints[i].y);

    // curve to next anchor through control
    var b1:Point = new Point(controlPoints[i].x,controlPoints[i].y);
    var p1:Point = derivePoint(p0, b1, p2);

    g.curveTo(p1.x, p1.y, p2.x, p2.y);

    p0 = p2;

}
// Close the loop
g.curveTo(controlPoints[0].x,controlPoints[0].y,startX,startY);

示例项目源代码

于 2010-01-16T03:39:11.523 回答